GNOME.org
 

gnome-power-manager r2878 - trunk

Author: gdartigu
Date: Wed Aug 13 20:14:33 2008
New Revision: 2878
URL: http://svn.gnome.org/viewvc/gnome-power-manager?rev=2878&view=rev

Log:
2008-08-13  Gilles Dartiguelongue  <gdartigu svn gnome org>

	* Makefile.am:
	* configure.ac: enhance autofoo readability and fix a typo
	with the gconf-defaults option. Fixes #547502.



Modified:
   trunk/ChangeLog
   trunk/Makefile.am
   trunk/configure.ac

Modified: trunk/Makefile.am
==============================================================================
--- trunk/Makefile.am	(original)
+++ trunk/Makefile.am	Wed Aug 13 20:14:33 2008
@@ -1,3 +1,6 @@
+
+ACLOCAL_AMFLAGS = -I m4
+
 SUBDIRS =						\
 	libdbus-glib					\
 	libhal-glib					\

Modified: trunk/configure.ac
==============================================================================
--- trunk/configure.ac	(original)
+++ trunk/configure.ac	Wed Aug 13 20:14:33 2008
@@ -1,11 +1,14 @@
-AC_PREREQ(2.52)
+AC_PREREQ(2.60)
 
 AC_INIT(gnome-power-manager, 2.23.6)
 AC_CONFIG_SRCDIR(src)
 AM_INIT_AUTOMAKE(AC_PACKAGE_NAME, AC_PACKAGE_VERSION)
 AM_CONFIG_HEADER(config.h)
+AC_CONFIG_MACRO_DIR([m4])
 
 AC_PROG_CC
+AM_PROG_CC_C_O
+
 AC_PROG_INSTALL
 AM_PROG_LIBTOOL
 IT_PROG_INTLTOOL([0.35.0])
@@ -100,33 +103,33 @@
 AC_SUBST(GSTREAMER_CFLAGS)
 AC_SUBST(GSTREAMER_LIBS)
 
-PKG_CHECK_MODULES(DBUS, \
- dbus-glib-1 >= $DBUS_REQUIRED \
- dbus-1 >= $DBUS_REQUIRED \
- gthread-2.0)
+PKG_CHECK_MODULES(DBUS,[
+ dbus-glib-1 >= $DBUS_REQUIRED
+ dbus-1 >= $DBUS_REQUIRED
+ gthread-2.0])
 AC_SUBST(DBUS_CFLAGS)
 AC_SUBST(DBUS_LIBS)
 
-PKG_CHECK_MODULES(GNOME, \
- libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED \
- libglade-2.0 >= $LIBGLADE_REQUIRED \
- libwnck-1.0 >= $LIBWNCK_REQUIRED \
- gtk+-2.0 >= $GTK_REQUIRED \
- gnome-keyring-1 >= $GNOME_KEYRING_REQUIRED \
- libpanelapplet-2.0 >= $LIBPANEL_REQUIRED \
- cairo >= $CAIRO_REQUIRED)
+PKG_CHECK_MODULES(GNOME, [
+ libgnomeui-2.0 >= $LIBGNOMEUI_REQUIRED
+ libglade-2.0 >= $LIBGLADE_REQUIRED
+ libwnck-1.0 >= $LIBWNCK_REQUIRED
+ gtk+-2.0 >= $GTK_REQUIRED
+ gnome-keyring-1 >= $GNOME_KEYRING_REQUIRED
+ libpanelapplet-2.0 >= $LIBPANEL_REQUIRED
+ cairo >= $CAIRO_REQUIRED])
 AC_SUBST(GNOME_CFLAGS)
 AC_SUBST(GNOME_LIBS)
 
-PKG_CHECK_MODULES(GDK, \
- gdk-2.0 >= $GDK_REQUIRED \
- gdk-x11-2.0 >= $GDK_REQUIRED)
+PKG_CHECK_MODULES(GDK, [
+ gdk-2.0 >= $GDK_REQUIRED
+ gdk-x11-2.0 >= $GDK_REQUIRED])
 AC_SUBST(GDK_CFLAGS)
 AC_SUBST(GDK_LIBS)
 
-PKG_CHECK_MODULES(XRANDR, \
- xrandr >= $XRANDR_REQUIRED \
- xrender x11)
+PKG_CHECK_MODULES(XRANDR, [
+ xrandr >= $XRANDR_REQUIRED 
+ xrender x11])
 AC_SUBST(XRANDR_CFLAGS)
 AC_SUBST(XRANDR_LIBS)
 
@@ -149,8 +152,9 @@
 dnl - Where should we put documentation ?
 dnl ---------------------------------------------------------------------------
 AC_ARG_WITH(doc-dir,
-              [AC_HELP_STRING([--with-doc-dir=<dir>],
-              [directory to install documentation])])
+            AS_HELP_STRING([--with-doc-dir=<dir>],
+                           [directory to install documentation]))
+
 if ! test -z "$with_doc_dir"; then
    DOCDIR="$with_doc_dir/gnome-power-manager-$VERSION"
 else
@@ -161,10 +165,14 @@
 dnl ---------------------------------------------------------------------------
 dnl - PolicyKit support?
 dnl ---------------------------------------------------------------------------
-AC_ARG_ENABLE(policykit, [  --enable-policykit      support PolicyKit permissions daemon (requires polkitd)],enable_polkit=$enableval,enable_polkit=no)
+AC_ARG_ENABLE(policykit,
+              AS_HELP_STRING([--enable-policykit],
+                             [support PolicyKit permissions daemon (requires polkitd)]),
+              enable_policykit=$enableval,enable_policykit=no)
+
 AC_MSG_CHECKING([whether to support PolicyKit])
 have_polkit=no
-if test x$enable_polkit = xyes ; then
+if test x$enable_policykit = xyes ; then
     PKG_CHECK_MODULES(POLKIT, \
                       polkit-grant >= $POLKIT_GNOME_REQUIRED\
                       polkit-dbus >= $POLKIT_GNOME_REQUIRED)
@@ -172,77 +180,116 @@
     AC_SUBST(POLKIT_LIBS)
     have_polkit=yes
     AC_DEFINE(HAVE_POLKIT, 1, [Define if we use PolicyKit])
+    AC_MSG_RESULT(yes)
+else
+    AC_MSG_RESULT(no)
 fi
-#AC_MSG_RESULT(yes)
 
 dnl ---------------------------------------------------------------------------
 dnl - Use check-foreground-console (Ubuntu specific) support?
 dnl ---------------------------------------------------------------------------
-AC_ARG_ENABLE(checkfg, [  --enable-checkfg        Use check-foreground-console (Ubuntu systems)],enable_checkfg=$enableval,enable_checkfg=no)
+AC_ARG_ENABLE(checkfg,
+              AS_HELP_STRING([--enable-checkfg],
+                             [Use check-foreground-console (Ubuntu systems)]),
+              enable_checkfg=$enableval,enable_checkfg=no)
+
 AC_MSG_CHECKING([whether to use check-foreground-console])
 have_checkfg=no
 if test x$enable_checkfg = xyes ; then
     have_checkfg=yes
     AC_DEFINE(HAVE_CHECK_FG, 1, [Define if we want to use check-foreground-console])
+    AC_MSG_RESULT(yes)
+else
+    AC_MSG_RESULT(no)
 fi
-#AC_MSG_RESULT(yes)
 
 dnl ---------------------------------------------------------------------------
 dnl - Respond to XEvents
 dnl ---------------------------------------------------------------------------
-AC_ARG_ENABLE(xevents, [  --enable-xevents        Support XEVENTS (requires a new x.org)],enable_xevents=$enableval,enable_xevents=yes)
+AC_ARG_ENABLE(xevents,
+              AS_HELP_STRING([--disable-xevents],
+                             [Support XEVENTS (requires a new x.org)]),
+              enable_xevents=$enableval,enable_xevents=yes)
+
 AC_MSG_CHECKING([whether to support xevents])
 have_xevents=no
 if test x$enable_xevents = xyes ; then
     have_xevents=yes
     AC_DEFINE(HAVE_XEVENTS, 1, [Define if we use XEVENTS])
+    AC_MSG_RESULT(yes)
+else
+    AC_MSG_RESULT(no)
 fi
 
 dnl ---------------------------------------------------------------------------
 dnl - Build self tests
 dnl ---------------------------------------------------------------------------
-AC_ARG_ENABLE(tests, [  --enable-tests          Build self tests],enable_tests=$enableval,enable_tests=no)
+AC_ARG_ENABLE(tests,
+              AS_HELP_STRING([--enable-tests],
+                             [Build self tests]),
+              enable_tests=$enableval,enable_tests=no)
+
 AC_MSG_CHECKING([whether to support tests])
 have_tests=no
 if test x$enable_tests = xyes ; then
     have_tests=yes
     AC_DEFINE(HAVE_TESTS, 1, [Define if we want to use the self tests])
+    AC_MSG_RESULT(yes)
+else
+    AC_MSG_RESULT(no)
 fi
 AM_CONDITIONAL([HAVE_TESTS], [test $have_tests = yes])
 
 dnl ---------------------------------------------------------------------------
 dnl - Build gconf default button?
 dnl ---------------------------------------------------------------------------
-AC_ARG_ENABLE(gconfdefaults, [  --enable-gconf-defaults        Allow setting gconf default settings],
+AC_ARG_ENABLE(gconf-defaults,
+              AS_HELP_STRING([--disable-gconf-defaults],
+                             [Allow setting gconf default settings]),
               enable_gconfdefaults=$enableval,enable_gconfdefaults=yes)
+
 AC_MSG_CHECKING([whether to support gconf defaults])
 have_gconfdefaults=no
 if test x$enable_gconfdefaults = xyes ; then
-    PKG_CHECK_MODULES(POLKIT_GNOME, \
-                      polkit-gnome >= $POLKIT_GNOME_REQUIRED)
+    PKG_CHECK_MODULES(POLKIT_GNOME, [
+                      polkit-gnome >= $POLKIT_GNOME_REQUIRED])
     AC_SUBST(POLKIT_GNOME_CFLAGS)
     AC_SUBST(POLKIT_GNOME_LIBS)
     have_gconfdefaults=yes
     AC_DEFINE(HAVE_GCONF_DEFAULTS, 1, [Define if have policykit-gnome])
+    AC_MSG_RESULT(yes)
+else
+    AC_MSG_RESULT(no)
 fi
 AM_CONDITIONAL([HAVE_GCONF_DEFAULTS], [test $have_gconfdefaults = yes])
 
 dnl ---------------------------------------------------------------------------
 dnl - Build applets
 dnl ---------------------------------------------------------------------------
-AC_ARG_ENABLE(applets, [  --enable-applets        Build the extra power applets],enable_applets=$enableval,enable_applets=yes)
+AC_ARG_ENABLE(applets,
+              AS_HELP_STRING([--disable-applets],
+                             [Build the extra power applets]),
+              enable_applets=$enableval,enable_applets=yes)
+
 AC_MSG_CHECKING([whether to build applet support])
 have_applets=no
 if test x$enable_applets = xyes ; then
     have_applets=yes
     AC_DEFINE(HAVE_APPLETS, 1, [Define if we are building applets])
+    AC_MSG_RESULT(yes)
+else
+    AC_MSG_RESULT(no)
 fi
 AM_CONDITIONAL([HAVE_APPLETS], [test $have_applets = yes])
 
 dnl ---------------------------------------------------------------------------
 dnl - DocBook Documentation
 dnl ---------------------------------------------------------------------------
-AC_ARG_ENABLE(docbook-docs, [  --enable-docbook-docs   build documentation (requires xmlto)],enable_docbook_docs=$enableval,enable_docbook_docs=auto)
+AC_ARG_ENABLE(docbook-docs,
+              AS_HELP_STRING([--enable-docbook-docs],
+                             [build documentation (requires xmlto)]),
+              enable_docbook_docs=$enableval,enable_docbook_docs=auto)
+
 AC_PATH_PROG(XMLTO, xmlto, no)
 AC_MSG_CHECKING([whether to build DocBook documentation])
 if test x$XMLTO = xno ; then
@@ -269,8 +316,9 @@
 dnl - Are we specifying a different dbus root ?
 dnl ---------------------------------------------------------------------------
 AC_ARG_WITH(dbus-services,
-              [AC_HELP_STRING([--with-dbus-services=<dir>],
-              [where D-BUS services directory is])])
+            AS_HELP_STRING([--with-dbus-services=<dir>],
+                           [where D-BUS services directory is]))
+
 if ! test -z "$with_dbus_services" ; then
 	DBUS_SERVICES_DIR="$with_dbus_services"
 else
@@ -424,9 +472,11 @@
 have_dpms=no
 with_dpms_req=unspecified
 GPM_EXTRA_LIBS="-lresolv"
+
 AC_ARG_WITH(dpms-ext,
-[  --with-dpms-ext         Include support for the DPMS extension.],
-  [with_dpms="$withval"; with_dpms_req="$withval"],[with_dpms=yes])
+            AS_HELP_STRING([--without-dpms-ext],
+                           [Include support for the DPMS extension.]),
+            [with_dpms="$withval"; with_dpms_req="$withval"],[with_dpms=yes])
 
 HANDLE_X_PATH_ARG(with_dpms, --with-dpms-ext, DPMS)
 
@@ -469,9 +519,10 @@
 dnl ---------------------------------------------------------------------------
 AC_MSG_CHECKING(for Solaris kstat)
 AC_CHECK_LIB(kstat, kstat_open,
-             [AC_DEFINE(HAVE_KSTAT, 1, [Define if Solaris kstat is support])
-             GPM_EXTRA_LIBS="$GPM_EXTRA_LIBS -lkstat"])
-
+	     [
+	       AC_DEFINE(HAVE_KSTAT, 1, [Define if Solaris kstat is support])
+	       GPM_EXTRA_LIBS="$GPM_EXTRA_LIBS -lkstat"
+	     ])
 AC_SUBST(GPM_EXTRA_LIBS)
 
 dnl ---------------------------------------------------------------------------
@@ -480,7 +531,7 @@
 AC_PATH_PROG(DOCBOOK2MAN, docbook2man, no)
 if test "$DOCBOOK2MAN" = "no" ; then
 	AC_MSG_WARN([docbook2man not found, will not be able to build man documentation])
-	fi
+fi
 AM_CONDITIONAL(HAVE_DOCBOOK2MAN, [test "$DOCBOOK2MAN" != "no"])
 
 dnl ------------------------------------------------------------------------------
@@ -488,7 +539,8 @@
 dnl ------------------------------------------------------------------------------
 
 AC_ARG_ENABLE(more-warnings,
-  AC_HELP_STRING([--enable-more-warnings], [Maximum compiler warnings]),
+              AS_HELP_STRING([--enable-more-warnings],
+                             [Maximum compiler warnings]),
 set_more_warnings="$enableval",[
 if test -d $srcdir/CVS; then
         is_cvs_version=true
@@ -529,7 +581,7 @@
 dnl ---------------------------------------------------------------------------
 dnl - Makefiles, etc.
 dnl ---------------------------------------------------------------------------
-AC_OUTPUT([
+AC_CONFIG_FILES([
 Makefile
 src/Makefile
 src/dbus/Makefile
@@ -574,6 +626,8 @@
 data/icons/scalable/status/Makefile
 ])
 
+AC_OUTPUT
+
 dnl ==========================================================================
 echo "
                     GNOME Power Manager $VERSION
@@ -595,6 +649,6 @@
         documentation dir:         $DOCDIR
         dbus-1 system.d dir:       $DBUS_SYS_DIR
         dbus-1 services dir:       $DBUS_SERVICES_DIR
-	gconf-schema dir:          $GCONF_SCHEMA_FILE_DIR
+        gconf-schema dir:          $GCONF_SCHEMA_FILE_DIR
 "
[Date Prev][Date Next]   [Thread Prev][Thread Next]   [Thread Index] [Date Index] [Author Index]