gnome-media r3956 - in trunk: . cddb-slave2 gnome-cd gnome-cd/access grecord grecord/src gst-mixer/src gstreamer-properties m4 vu-meter
- From: gdartigu svn gnome org
- To: svn-commits-list gnome org
- Subject: gnome-media r3956 - in trunk: . cddb-slave2 gnome-cd gnome-cd/access grecord grecord/src gst-mixer/src gstreamer-properties m4 vu-meter
- Date: Sun, 7 Sep 2008 18:15:44 +0000 (UTC)
Author: gdartigu
Date: Sun Sep 7 18:15:44 2008
New Revision: 3956
URL: http://svn.gnome.org/viewvc/gnome-media?rev=3956&view=rev
Log:
Modernize autofoo, bug #550919.
- Rename configure.in to configure.ac
- use a modern version of AS_VERSION
- remove duplicate of ACLOCAL flags
- remove tabs and trailing ws
- print CFLAGS using GNOME_COMPILE_FLAGS
- change autogen.sh accordingly
- remove the weird unused MAIL_TRANSFERT_AGENT
- make a more appropriate summary by moving gnome-cd and deprecated stuff to the end.
Patch by Marc-Andrà Lureau <marcandre lureau gmail com>
and Gilles Dartiguelongue <gdartigu svn gnome org>.
Added:
trunk/configure.ac (contents, props changed)
- copied, changed from r3955, /trunk/configure.in
Removed:
trunk/configure.in
Modified:
trunk/ChangeLog
trunk/Makefile.am
trunk/autogen.sh
trunk/cddb-slave2/ChangeLog
trunk/cddb-slave2/Makefile.am
trunk/gnome-cd/ChangeLog
trunk/gnome-cd/Makefile.am
trunk/gnome-cd/access/Makefile.am
trunk/grecord/ChangeLog
trunk/grecord/src/Makefile.am
trunk/gst-mixer/src/Makefile.am
trunk/gstreamer-properties/ChangeLog
trunk/gstreamer-properties/Makefile.am
trunk/m4/as-version.m4
trunk/vu-meter/ChangeLog
trunk/vu-meter/Makefile.am
Modified: trunk/Makefile.am
==============================================================================
--- trunk/Makefile.am (original)
+++ trunk/Makefile.am Sun Sep 7 18:15:44 2008
@@ -1,18 +1,40 @@
-SUBDIRS = po \
- @PROGRAMS_GMP@ \
- @PROGRAMS_CDDBSLAVE@ \
- @PROGRAMS_VUMETER@ \
- @PROGRAMS_GSTMIXER@ \
- @PROGRAMS_GNOME_CD@ \
- @PROGRAMS_GRECORD@ \
- @PROGRAMS_GSTPROPS@
+SUBDIRS = po
+
+if HAVE_GMP
+SUBDIRS += profiles
+endif
+
+if HAVE_CDDBSLAVE
+SUBDIRS += cddb-slave2
+endif
+
+if HAVE_VUMETER
+SUBDIRS += vu-meter
+endif
+
+if HAVE_GRECORD
+SUBDIRS += grecord
+endif
+
+if HAVE_GNOMECD
+SUBDIRS += gnome-cd
+endif
+
+if HAVE_GSTMIXER
+SUBDIRS += gst-mixer
+endif
+
+if HAVE_GSTPROPS
+SUBDIRS += gstreamer-properties
+endif
INTLTOOL_BUILT = \
intltool-extract \
intltool-merge \
intltool-update
-DISTCHECK_CONFIGURE_FLAGS = --disable-scrollkeeper
+DISTCHECK_CONFIGURE_FLAGS = --disable-scrollkeeper --enable-cddbslave \
+--enable-vumeter --enable-gnomecd --enable-compile-warnings=maximum
DIST_SUBDIRS = po profiles cddb-slave2 \
vu-meter grecord gst-mixer gnome-cd \
Modified: trunk/autogen.sh
==============================================================================
--- trunk/autogen.sh (original)
+++ trunk/autogen.sh Sun Sep 7 18:15:44 2008
@@ -5,9 +5,9 @@
test -z "$srcdir" && srcdir=.
PKG_NAME="gnome-media"
-REQUIRED_AUTOMAKE_VERSION=1.7
+REQUIRED_AUTOMAKE_VERSION=1.9
-(test -f $srcdir/configure.in \
+(test -f $srcdir/configure.ac \
&& test -d $srcdir/cddb-slave2) || {
echo -n "**Error**: Directory "\`$srcdir\'" does not look like the"
echo " top-level $PKG_NAME directory"
@@ -21,7 +21,4 @@
REQUIRED_INTLTOOL_VERSION=0.35
-# fix doc build before turning on common doc build
-# USE_GNOME2_MACROS=1 USE_COMMON_DOC_BUILD=yes . gnome-autogen.sh
-# set ACLOCAL_AMFLAGS
-USE_GNOME2_MACROS=1 ACLOCAL_FLAGS="$ACLOCAL_FLAGS -I m4" . gnome-autogen.sh
+USE_GNOME2_MACROS=1 USE_COMMON_DOC_BUILD=yes . gnome-autogen.sh
Modified: trunk/cddb-slave2/Makefile.am
==============================================================================
--- trunk/cddb-slave2/Makefile.am (original)
+++ trunk/cddb-slave2/Makefile.am Sun Sep 7 18:15:44 2008
@@ -1,5 +1,5 @@
### compile flags used by all objects
-INCLUDES = \
+AM_CPPFLAGS = \
-I$(top_srcdir) \
-I$(top_builddir) \
$(CDDBSLAVE_CFLAGS) \
Copied: trunk/configure.ac (from r3955, /trunk/configure.in)
==============================================================================
--- /trunk/configure.in (original)
+++ trunk/configure.ac Sun Sep 7 18:15:44 2008
@@ -1,19 +1,22 @@
-AC_PREREQ(2.53)
-AC_INIT(cddb-slave2)
+AC_PREREQ(2.60)
-AS_VERSION(gnome-media, GNOME_MEDIA_VERSION, 2, 23, 92, 0,
- GM_RELEASE="yes", GM_RELEASE="no")
+AC_INIT([gnome-media],
+ [2.23.92],
+ [http://bugzilla.gnome.org/enter_bug.cgi?product=gnome-media])
+
+AM_INIT_AUTOMAKE([-Wall -Wno-portability -Werror])
+
+AS_VERSION
AM_MAINTAINER_MODE
-AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
-AC_SUBST(ACLOCAL_AMFLAGS, "$ACLOCAL_FLAGS -I m4")
if type -p stow > /dev/null && test -d /usr/local/stow ; then
AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE}-${VERSION} ***])
ac_default_prefix="/usr/local/stow/${PACKAGE}-${VERSION}"
fi
-AM_CONFIG_HEADER(config.h)
+AM_CONFIG_HEADER([config.h])
+AC_CONFIG_MACRO_DIR([m4])
IT_PROG_INTLTOOL([0.35.0])
@@ -27,7 +30,7 @@
# Checks for header files.
AC_HEADER_STDC
-AC_CHECK_HEADERS(fcntl.h limits.h malloc.h strings.h sys/ioctl.h unistd.h)
+AC_CHECK_HEADERS([fcntl.h limits.h malloc.h strings.h sys/ioctl.h unistd.h])
AC_CHECK_HEADERS([sys/sockio.h sys/param.h])
# Checks for typedefs, structures, and compiler characteristics.
@@ -37,52 +40,61 @@
AC_TYPE_SIZE_T
# Checks for library functions.
-#AC_FUNC_ALLOCA
AC_PROG_GCC_TRADITIONAL
AC_FUNC_MMAP
-#AC_CHECK_FUNCS(getcwd getwd putenv strdup strerror)
-AC_DEFINE_UNQUOTED(DEFAULT_MIXER, gst-mixer, [default mixer to use])
+# CFLAGS
+GNOME_COMPILE_WARNINGS
-dnl error flags
-GM_ERROR_CFLAGS=""
-dnl always use -Wall if it's supported
+AS_NANO(GM_RELEASE="yes", GM_RELEASE="no")
AS_COMPILER_FLAG(-Wall, GM_ERROR_CFLAGS="-Wall")
-dnl if we're not in release mode, add -Werror if supported
+
if test "x$GM_RELEASE" = "xno"
then
AS_COMPILER_FLAG(-Werror, GM_ERROR_CFLAGS="$GM_ERROR_CFLAGS -Werror")
fi
AC_MSG_NOTICE([Using $GM_ERROR_CFLAGS as error checking CFLAGS])
-dnl Start of pkg-config checks
+dnl=======================================================================
+dnl Start of pkg-config checks - common libs
+dnl=======================================================================
+
PKG_CHECK_MODULES(MEDIA, [
- glib-2.0 >= 1.3.7
- gmodule-2.0 >= 1.3.7
- libgnome-2.0 >= 2.13.7
- libgnomeui-2.0 >= 2.13.2
+ glib-2.0 >= 1.3.7
+ gmodule-2.0 >= 1.3.7
+ libgnome-2.0 >= 2.13.7
+ libgnomeui-2.0 >= 2.13.2
])
+
host=`uname -s`
case "$host" in
*SunOS*)
- MEDIA_LIBS="$MEDIA_LIBS -ldevinfo -lX11"
+ MEDIA_LIBS="$MEDIA_LIBS -ldevinfo -lX11"
;;
esac
AC_SUBST(MEDIA_CFLAGS)
AC_SUBST(MEDIA_LIBS)
-# Check for the CDDBSlave2 modules
-PROGRAMS_CDDBSLAVE=""
-AC_ARG_ENABLE([cddbslave],AC_HELP_STRING([--enable-cddbslave], [ enable gnome cd database ]), ,enable_cddbslave=no)
-if test "x$enable_cddbslave" == "xyes"; then
- PKG_CHECK_MODULES(CDDBSLAVE, glib-2.0 >= 1.3.7 \
- gmodule-2.0 >= 1.3.7 \
- libbonobo-2.0 >= 2.0.0 \
- libgnomeui-2.0 >= 1.102.0, \
- PROGRAMS_CDDBSLAVE="cddb-slave2", \
- PROGRAMS_CDDBSLAVE="")
+dnl=======================================================================
+dnl Check for the CDDBSlave2 modules
+dnl=======================================================================
+
+have_cddbslave=no
+
+AC_ARG_ENABLE([cddbslave],
+ AS_HELP_STRING([--enable-cddbslave], [enable gnome cd database]),
+ ,enable_cddbslave=no)
+
+if test "x$enable_cddbslave" != "xno"; then
+ PKG_CHECK_MODULES(CDDBSLAVE, [
+ glib-2.0 >= 1.3.7
+ gmodule-2.0 >= 1.3.7
+ libbonobo-2.0 >= 2.0.0
+ libgnomeui-2.0 >= 1.102.0],
+ have_cddbslave=yes)
fi
+
# Check for network stuff
AC_CHECK_FUNCS(poll basename)
AC_CHECK_FUNC(inet_aton,,[AC_CHECK_LIB(resolv,inet_aton,CDDBSLAVE_LIBS="$CDDBSLAVE_LIBS -lresolv")])
@@ -92,31 +104,34 @@
dnl=======================================================================
dnl IPv6 related checks
dnl=======================================================================
-AC_MSG_CHECKING([whether to enable IPv6])
-AC_ARG_ENABLE(ipv6,AC_HELP_STRING( [--enable-ipv6],[enable IPv6 extension]), ,enable_ipv6=yes)
-if test $enable_ipv6 = yes; then
+
+have_ipv6=no
+
+AC_ARG_ENABLE(ipv6,
+ AS_HELP_STRING([--enable-ipv6],[enable IPv6 extension]),
+ ,enable_ipv6=yes)
+
+if test "x$enable_ipv6" = "xyes"; then
+ AC_MSG_CHECKING([whether to enable IPv6])
AC_TRY_COMPILE([
#include <sys/types.h>
#include <sys/socket.h>], [
struct sockaddr_storage ss;
socket(AF_INET6, SOCK_STREAM, 0)
- ],
- have_ipv6=yes,
- have_ipv6=no
- )
+ ], have_ipv6=yes)
AC_MSG_RESULT($have_ipv6)
- if test $have_ipv6 = yes; then
+ if test "x$have_ipv6" = "xyes"; then
have_getaddrinfo=no
AC_CHECK_FUNC(getaddrinfo, have_getaddrinfo=yes)
- if test $have_getaddrinfo = no; then
+ if test "x$have_getaddrinfo" = "xno"; then
for lib in bsd socket inet; do
AC_CHECK_LIB($lib,getaddrinfo,[LIBS="$LIBS -l$lib";have_getaddrinfo=yes;break])
done
fi
- if test $have_getaddrinfo = yes; then
+ if test "x$have_getaddrinfo" = "xyes"; then
AC_DEFINE(ENABLE_IPV6, 1, [Define if we have IPv6 support])
fi
fi
@@ -126,79 +141,92 @@
dnl IPv6 related checks ends..
dnl=======================================================================
-AC_SUBST(CDDBSLAVE_LIBS)
AC_SUBST(CDDBSLAVE_CFLAGS, "$CDDBSLAVE_CFLAGS $GM_ERROR_CFLAGS")
-AC_SUBST(PROGRAMS_CDDBSLAVE)
+AC_SUBST(CDDBSLAVE_LIBS)
+AM_CONDITIONAL(HAVE_CDDBSLAVE, [test x$have_cddbslave = xyes])
-# profiles
-PROGRAMS_GMP=""
-AC_ARG_ENABLE([profiles],AC_HELP_STRING([--enable-profiles], [ enable gnome media profiles ]), ,enable_profiles=yes)
-if test "x$enable_profiles" == "xyes"; then
- PKG_CHECK_MODULES(GMP, gstreamer-0.10 gconf-2.0 libglade-2.0 libgnomeui-2.0 gio-2.0,
- PROGRAMS_GMP="profiles", PROGRAMS_GMP="")
+dnl=======================================================================
+dnl profiles
+dnl=======================================================================
+
+have_profiles=no
+
+AC_ARG_ENABLE([profiles],
+ AS_HELP_STRING([--enable-profiles], [enable gnome media profiles]),
+ ,enable_profiles=yes)
+
+if test "x$enable_profiles" = "xyes"; then
+ PKG_CHECK_MODULES(GMP, [
+ gstreamer-0.10
+ gconf-2.0
+ libglade-2.0
+ libgnomeui-2.0
+ gio-2.0],
+ have_profiles=yes)
fi
AC_SUBST(GMP_CFLAGS)
AC_SUBST(GMP_LIBS)
-AC_SUBST(PROGRAMS_GMP)
+AM_CONDITIONAL(HAVE_GMP, [test x$have_profiles = xyes])
-# Check for GStreamer stuff and GSR depds
-HAVE_GST=no
+dnl=======================================================================
+dnl Check for GStreamer and GSR deps
+dnl=======================================================================
GST_REQ=0.10.3
-GSTPB_REQ=0.10.3
-
-PROGRAMS_GSTRECORD=""
-
-dnl start with 0.10
+GST_PLUGINS_BASE_REQ=0.10.3
GST_MAJORMINOR=0.10
+
dnl make available to Makefile.am
AC_SUBST(GST_MAJORMINOR)
AC_DEFINE_UNQUOTED(GST_MAJORMINOR_QUOTED, "$GST_MAJORMINOR",
[major/minor of GStreamer as a string constant])
-dnl gstreamer-libs-$GST_MAJORMINOR >= $GST_REQ
-dnl gstreamer-gconf-$GST_MAJORMINOR >= $GST_REQ
+have_gst=no
-HAVE_GST=no
-PKG_CHECK_MODULES(GSR, \
- gstreamer-$GST_MAJORMINOR >= $GST_REQ \
- gstreamer-plugins-base-$GST_MAJORMINOR >= $GST_REQ \
- gtk+-2.0 >= 2.6.0 libgnomeui-2.0 >= 1.102.0 gio-2.0,
- HAVE_GST=yes,
+PKG_CHECK_MODULES(GSR, [
+ gstreamer-$GST_MAJORMINOR >= $GST_REQ
+ gstreamer-plugins-base-$GST_MAJORMINOR >= $GST_REQ
+ gtk+-2.0 >= 2.6.0
+ libgnomeui-2.0 >= 1.102.0
+ gio-2.0],
+ have_gst=yes,
[
- HAVE_GST=no
AC_MSG_RESULT(no)
AC_MSG_WARN($GSR_PKG_ERRORS)
PROGRAMS_GRECORD_ERROR="$GSR_PKG_ERRORS"
])
-PROGRAMS_GRECORD=""
-AC_ARG_ENABLE([grecord],AC_HELP_STRING([--enable-grecord], [ enable gnome sound recorder ]), ,enable_grecord=yes)
+have_grecord=no
+grecord_reason=""
-if test -z "$PROGRAMS_GMP" ; then
- AC_MSG_WARN([ Grecord will be disabled because of disabled profiles])
- enable_grecord="no"
- PROGRAMS_GRECORD_ERROR=" gnome media profiles is disabled"
-fi
+AC_ARG_ENABLE([grecord],
+ AS_HELP_STRING([--enable-grecord], [enable gnome sound recorder]),
+ ,enable_grecord=yes)
+
+if test "x$have_profiles" = "xno" ; then
+ AC_MSG_WARN([Grecord will be disabled because of disabled profiles])
+ enable_grecord=no
+ have_grecord=no
+ grecord_reason=", gnome media profiles is disabled"
+fi
-if test "x$HAVE_GST" = "xyes" && test "x$enable_grecord" == "xyes"; then
- PROGRAMS_GRECORD="grecord"
+if test "x$have_gst" = "xyes" && test "x$enable_grecord" = "xyes"; then
+ have_grecord=yes
else
- if test "x$HAVE_GST" = "xno"; then
+ if test "x$have_gst" = "xno"; then
AC_MSG_WARN([You need GStreamer installed for the mixer and recorder to work])
sleep 5 2>/dev/null
fi
fi
-AC_SUBST(PROGRAMS_GRECORD)
-AM_CONDITIONAL(HAVE_GSTREAMER, test "x$HAVE_GST" = "xyes")
-
AC_SUBST(GSR_CFLAGS)
AC_SUBST(GSR_LIBS)
+AM_CONDITIONAL(HAVE_GSTREAMER, [test x$have_gst = xyes])
+AM_CONDITIONAL(HAVE_GRECORD, [test x$have_grecord = xyes])
dnl uninstalled gsr ui dir
AC_DEFINE_UNQUOTED(GSR_UIDIR_UNINSTALLED, "`pwd`/grecord/src",
- [path to uninstalled gnome-sound-recorder UI dir])
+ [path to uninstalled gnome-sound-recorder UI dir])
AC_PATH_PROG(GCONFTOOL, gconftool-2)
AM_GCONF_SOURCE_2
@@ -213,104 +241,128 @@
ORBIT_IDL="`$PKG_CONFIG --variable=orbit_idl ORBit-2.0`"
AC_SUBST(ORBIT_IDL)
-# Check for esound library
-got_esd=no
-AM_PATH_ESD(0.2.7, we_have_esd=true)
-if test -n "$we_have_esd"; then
- got_esd=yes
- AC_DEFINE(HAVE_ESD, 1, [Defined if we have Esound])
+dnl=======================================================================
+dnl Check for esound library
+dnl=======================================================================
+
+have_esd=no
+
+AC_ARG_ENABLE([esound],
+ AS_HELP_STRING([--enable-esound], [enable support for esound daemon]),
+ ,enable_esound=yes)
+
+if test "x$enable_esound" = "xyes"; then
+ AM_PATH_ESD(0.2.7, have_esd=yes)
+
+ if test "x$have_esd" = "xyes"; then
+ AC_DEFINE(HAVE_ESD, 1, [Defined if we have Esound])
+ fi
fi
-GNOME_DOC_INIT
+dnl=======================================================================
+dnl Test whether jw is installed
+dnl=======================================================================
-# Test whether jw is installed
AC_PATH_PROG(JW,jw,no)
if test x$JW = xno; then
HAVE_JW="no"
else
HAVE_JW="yes"
fi
-AM_CONDITIONAL(HAVE_JW, test "x$HAVE_JW" = "xyes")
+
+AM_CONDITIONAL(HAVE_JW, [test x$HAVE_JW = xyes])
AC_SUBST(HAVE_JW)
+dnl=======================================================================
+dnl i18n
+dnl=======================================================================
+
GETTEXT_PACKAGE=gnome-media-2.0
AC_SUBST(GETTEXT_PACKAGE)
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Define to the Gettext package name])
+AM_GLIB_GNU_GETTEXT
GNOME_DOC_INIT
AM_PROG_LIBTOOL
AM_PROG_CC_C_O
-AM_GLIB_GNU_GETTEXT
+dnl=======================================================================
+dnl vu-meter
+dnl=======================================================================
-AC_SUBST(CFLAGS)
-AC_SUBST(CPPFLAGS)
-AC_SUBST(LDFLAGS)
+have_vumeter=no
+vumeter_reason=""
-# vu-meter
-PROGRAMS_VUMETER=""
-AC_ARG_ENABLE([vumeter],AC_HELP_STRING([--enable-vumeter], [ enable vumeter ]), ,enable_vumeter=no)
-if test -n "$we_have_esd" && test "x$enable_vumeter" == "xyes"; then
- PKG_CHECK_MODULES(VUMETER, glib-2.0 >= 1.3.7 gtk+-2.0 >= 2.3.1 \
- esound >= 0.2.23 libgnomeui-2.0 > 1.102.0, \
- PROGRAMS_VUMETER="vu-meter", \
- PROGRAMS_VUMETER="")
+AC_ARG_ENABLE([vumeter],
+ AS_HELP_STRING([--enable-vumeter], [enable vumeter]),
+ ,enable_vumeter=no)
+
+if test "x$enable_vumeter" = "xyes" ; then
+ if test "x$have_esd" = "xyes"; then
+ PKG_CHECK_MODULES(VUMETER, [
+ glib-2.0 >= 1.3.7
+ gtk+-2.0 >= 2.3.1
+ esound >= 0.2.23
+ libgnomeui-2.0 > 1.102.0],
+ have_vumeter=yes)
+ else
+ AC_MSG_WARN([vu-meter disabled because esound couldn't be found])
+ vumeter_reason=", esound not found"
+ fi
fi
+
AC_SUBST(VUMETER_CFLAGS)
AC_SUBST(VUMETER_LIBS)
-AC_SUBST(PROGRAMS_VUMETER)
+AM_CONDITIONAL(HAVE_VUMETER, [test x$have_vumeter = xyes])
-# find the mailer for use with the submission helper
-# This code is from the gnome-bug script. It should work for most systems
-AC_MSG_CHECKING(for the MTA)
-if test -f /usr/sbin/sendmail; then
- MAIL_TRANSFER_AGENT="/usr/sbin/sendmail -t"
-elif test -f /usr/lib/sendmail; then
- MAIL_TRANSFER_AGENT="/usr/lib/sendmail -t"
-else
- MAIL_TRANSFER_AGENT="rmail "
-fi
-AC_DEFINE_UNQUOTED(MAIL_TRANSFER_AGENT, "$MAIL_TRANSFER_AGENT",
- [mail transfer agent command to use])
-AC_MSG_RESULT($MAIL_TRANSFER_AGENT)
+dnl=======================================================================
+dnl check for gnome-cd requirements
+dnl=======================================================================
-# check for gnome-cd requirements
# GStreamer is optional
# libnautilus-burn is required
-PROGRAMS_GNOME_CD=""
-HAVE_GNOMECD=no
-AC_ARG_ENABLE([gnomecd],AC_HELP_STRING([--enable-gnomecd], [ enable gnome cd player ]), ,enable_gnomecd=no)
-if test "x$enable_gnomecd" == "xyes"; then
- PKG_CHECK_MODULES(GNOMECD, \
- gstreamer-$GST_MAJORMINOR >= $GST_REQ \
- gstreamer-plugins-base-$GST_MAJORMINOR >= $GSTPB_REQ \
- libnautilus-burn >= 2.9.0 gtk+-2.0 >= 2.10.0,
- HAVE_GNOMECD=yes,
- [
- AC_MSG_RESULT(no)
- PKG_CHECK_MODULES(GNOMECD, libnautilus-burn >= 2.9.0 gtk+-2.0 >= 2.10.0,
- HAVE_GNOMECD=yes,
- [
- AC_MSG_RESULT(no)
- HAVE_GNOMECD=no
- ])
- ])
-fi
-if test -z "$PROGRAMS_CDDBSLAVE" ; then
- AC_MSG_WARN([ gnome-cd will be disabled because of disabled cddb-slave2])
- enable_gnomecd="no"
-fi
+have_gnomecd=no
+gnomecd_reason=""
-AC_SUBST(GNOMECD_CFLAGS)
-AC_SUBST(GNOMECD_LIBS)
+AC_ARG_ENABLE([gnomecd],
+ AS_HELP_STRING([--enable-gnomecd], [enable gnome cd player]),
+ ,enable_gnomecd=no)
+
+if test "x$have_cddbslave" = "xno" ; then
+ AC_MSG_WARN([gnome-cd will be disabled because of disabled cddb-slave2])
+ enable_gnomecd=no
+ have_gnomecd=no
+ gnomecd_reason=", missing cddb-slave support"
+fi
+
+if test "x$enable_gnomecd" = "xyes"; then
+ PKG_CHECK_MODULES(LIBXML2, [libxml-2.0 >= 2.5.0])
+
+ PKG_CHECK_MODULES(GNOMECD, [
+ gstreamer-$GST_MAJORMINOR >= $GST_REQ
+ gstreamer-plugins-base-$GST_MAJORMINOR >= $GST_PLUGINS_BASE_REQ
+ libnautilus-burn >= 2.9.0
+ gtk+-2.0 >= 2.10.0],
+ have_gnomecd=yes)
+
+ if test "x$have_gnomecd" = "xno"; then
+ PKG_CHECK_MODULES(GNOMECD, [
+ libnautilus-burn >= 2.9.0
+ gtk+-2.0 >= 2.10.0],
+ have_gnomecd=yes)
+ fi
+fi
-PKG_CHECK_MODULES(LIBXML2, libxml-2.0 >= 2.5.0,,HAVE_GNOMECD=no)
AC_SUBST(LIBXML2_CFLAGS)
AC_SUBST(LIBXML2_LIBS)
-if test "x$HAVE_GNOMECD" = "xyes" && test "x$enable_gnomecd" == "xyes" ; then
+AC_SUBST(GNOMECD_CFLAGS)
+AC_SUBST(GNOMECD_LIBS)
+AM_CONDITIONAL(HAVE_GNOMECD, [test x$have_gnomecd = xyes])
+
+if test "x$have_gnomecd" = "xyes" && test "x$enable_gnomecd" = "xyes" ; then
cdrom_header=""
AC_CHECK_HEADERS(linux/cdrom.h,[
PROGRAMS_GNOME_CD=gnome-cd
@@ -323,73 +375,73 @@
AC_CHECK_HEADERS(sun/dkio.h,[
PROGRAMS_GNOME_CD=gnome-cd
cdrom_header=sun/dkio.h])
-
+
AC_MSG_CHECKING([whether to use cd changer support])
AC_EGREP_CPP(answer_affirmatively,
[#include <linux/cdrom.h>
#ifdef CDROM_CHANGER_NSLOTS
- answer_affirmatively
+ answer_affirmatively
#endif
], cd_changer=yes, cd_changer=no)
if test "$cd_changer" = "yes"; then
- USE_CD_CHANGER="-DTCD_CHANGER_ENABLED"
+ USE_CD_CHANGER="-DTCD_CHANGER_ENABLED"
fi
AC_MSG_RESULT($cd_changer)
-
+
AC_SUBST(USE_CD_CHANGER)
AC_SUBST(PROGRAMS_GNOME_CD)
-
+
close_tray=no
AC_MSG_CHECKING([whether OS supports the CDROMCLOSETRAY ioctl])
AC_EGREP_CPP(answer_affirmatively,
[#include <$cdrom_header>
#ifdef CDROMCLOSETRAY
- answer_affirmatively
+ answer_affirmatively
#endif
], close_tray=yes)
if test "$close_tray" = "yes"; then
- AC_DEFINE(HAVE_CDROMCLOSETRAY_IOCTL, 1,
+ AC_DEFINE(HAVE_CDROMCLOSETRAY_IOCTL, 1,
[Defined if have an ioctl to close the CD-rom tray])
fi
AC_MSG_RESULT($close_tray)
-
+
host=`uname -s`
-
+
CDROM_HOST_BSD=false
CDROM_HOST_LINUX=false
CDROM_HOST_SOLARIS=false
case "$host" in
*FreeBSD*)
- CDROM_HOST=bsd
- CDROM_HOST_BSD=true
- default_cd_device="/dev/acd0c"
- ;;
+ CDROM_HOST=bsd
+ CDROM_HOST_BSD=true
+ default_cd_device="/dev/acd0c"
+ ;;
*NetBSD*)
- CDROM_HOST=bsd
- CDROM_HOST_BSD=true
- default_cd_device="/dev/rcd0d"
- ;;
- *Linux*)
- CDROM_HOST=linux
- CDROM_HOST_LINUX=true
- default_cd_device="/dev/cdrom"
- ;;
- *SunOS*)
- CDROM_HOST=solaris
- CDROM_HOST_SOLARIS=true
- default_cd_device="/vol/dev/aliases/cdrom0"
- ;;
+ CDROM_HOST=bsd
+ CDROM_HOST_BSD=true
+ default_cd_device="/dev/rcd0d"
+ ;;
+ *Linux*)
+ CDROM_HOST=linux
+ CDROM_HOST_LINUX=true
+ default_cd_device="/dev/cdrom"
+ ;;
+ *SunOS*)
+ CDROM_HOST=solaris
+ CDROM_HOST_SOLARIS=true
+ default_cd_device="/vol/dev/aliases/cdrom0"
+ ;;
esac
-
+
AC_SUBST(CDROM_HOST)
AC_SUBST(CDROM_HOST_BSD)
AC_SUBST(CDROM_HOST_LINUX)
AC_SUBST(CDROM_HOST_SOLARIS)
-
+
AC_SUBST(default_cd_device)
AC_DEFINE_UNQUOTED(default_cd_device, "$default_cd_device",
[Default CD device to use])
-
+
dnl uninstalled theme dir
AC_DEFINE_UNQUOTED(THEME_DIR_UNINSTALLED, "`pwd`/gnome-cd/images",
[path to uninstalled gnome-cd themes dir])
@@ -405,36 +457,54 @@
AM_CONDITIONAL(CDROM_HOST_LINUX, test "x$CDROM_HOST_LINUX" = "xtrue")
AM_CONDITIONAL(CDROM_HOST_SOLARIS, test "x$CDROM_HOST_SOLARIS" = "xtrue")
-# gstreamer-properties
-PROGRAMS_GSTPROPS=""
-AC_ARG_ENABLE([gstprops],AC_HELP_STRING([--enable-gstprops], [ enable gstreamer properties ]), ,enable_gstprops=yes)
-if test "x$HAVE_GST" = "xyes" && test "x$enable_gstprops" == "xyes";
+dnl=======================================================================
+dnl gstreamer-properties
+dnl=======================================================================
+
+have_gstprops=no
+
+AC_ARG_ENABLE([gstprops],
+ AS_HELP_STRING([--enable-gstprops], [enable gstreamer properties]),
+ ,enable_gstprops=yes)
+
+if test "x$have_gst" = "xyes" && test "x$enable_gstprops" = "xyes";
then
- dnl gstreamer-libs-$GST_MAJORMINOR
- dnl gstreamer-gconf-$GST_MAJORMINOR
- COMMON_MODULES="gconf-2.0 libgnomeui-2.0 libglade-2.0 >= 1.99.12 gstreamer-$GST_MAJORMINOR gstreamer-plugins-base-$GST_MAJORMINOR >= $GSTPB_REQ"
- PKG_CHECK_MODULES(GSTPROPS, $COMMON_MODULES libxml-2.0,
- PROGRAMS_GSTPROPS="gstreamer-properties")
+ PKG_CHECK_MODULES(GSTPROPS, [
+ gconf-2.0
+ libgnomeui-2.0
+ libglade-2.0 >= 1.99.12
+ gstreamer-$GST_MAJORMINOR
+ gstreamer-plugins-base-$GST_MAJORMINOR >= $GST_PLUGINS_BASE_REQ
+ libxml-2.0],
+ have_gstprops=yes)
+
GSTPROPS_LIBS="$GSTPROPS_LIBS -lgstinterfaces-$GST_MAJORMINOR"
- AC_SUBST(GSTPROPS_LIBS)
- AC_SUBST(GSTPROPS_CFLAGS)
GNOMECC_DESKTOP_DIR=${datadir}/control-center-2.0/capplets
AS_AC_EXPAND(GNOMECC_DESKTOP_DIR, $GNOMECC_DESKTOP_DIR)
- AC_DEFINE_UNQUOTED(GNOMECC_DESKTOP_DIR, "$GNOMECC_DESKTOP_DIR",
+ AC_DEFINE_UNQUOTED(GNOMECC_DESKTOP_DIR, "$GNOMECC_DESKTOP_DIR",
[Install path for Gnome control-center integration])
AC_SUBST(GNOMECC_DESKTOP_DIR)
AC_SUBST(PROGRAMS_GSTPROPS)
fi
-# gst-mixer
-PROGRAMS_GSTMIX=""
-AC_ARG_ENABLE([gstmix],AC_HELP_STRING([--enable-gstmix], [ enable gstreamer mixer ]), ,enable_gstmix=yes)
-if test "x$HAVE_GST" = "xyes" && test "x$enable_gstmix" == "xyes";
+AC_SUBST(GSTPROPS_CFLAGS)
+AC_SUBST(GSTPROPS_LIBS)
+AM_CONDITIONAL(HAVE_GSTPROPS, [test x$have_gstprops = xyes])
+
+dnl=======================================================================
+dnl gst-mixer
+dnl=======================================================================
+
+have_gstmixer=no
+
+AC_ARG_ENABLE([gstmix],
+ AS_HELP_STRING([--enable-gstmix], [enable gstreamer mixer]),
+ ,enable_gstmix=yes)
+
+if test "x$have_gst" = "xyes" && test "x$enable_gstmix" = "xyes";
then
- dnl gstreamer-interfaces-$GST_MAJORMINOR
- PKG_CHECK_MODULES(GSTMIXER,
- [
+ PKG_CHECK_MODULES(GSTMIXER, [
libgnomeui-2.0
gtk+-2.0
gconf-2.0
@@ -444,27 +514,28 @@
[
OLD_CPPFLAGS=$CPPFLAGS
CPPFLAGS="$CPPFLAGS $GSTMIXER_CFLAGS"
- PROGRAMS_GSTMIXER="gst-mixer"
- AC_CHECK_HEADER(gst/audio/mixerutils.h, , PROGRAMS_GSTMIXER="")
- if test "x$PROGRAMS_GSTMIXER" != "x"; then
- AC_CHECK_HEADER(gst/interfaces/mixer.h, , PROGRAMS_GSTMIXER="")
- fi
- if test "x$PROGRAMS_GSTMIXER" != "x"; then
- AC_CHECK_HEADER(gst/interfaces/propertyprobe.h, , PROGRAMS_GSTMIXER="")
- fi
+
+ AC_CHECK_HEADER(gst/audio/mixerutils.h,
+ [AC_CHECK_HEADER(gst/interfaces/mixer.h,
+ [AC_CHECK_HEADER(gst/interfaces/propertyprobe.h, have_gstmixer=yes)])])
+
CPPFLAGS=$OLD_CPPFLAGS
GSTMIXER_LIBS="$GSTMIXER_LIBS -lgstinterfaces-$GST_MAJORMINOR -lgstaudio-$GST_MAJORMINOR"
- ],
- [])
-
- AC_SUBST(GSTMIXER_LIBS)
- AC_SUBST(GSTMIXER_CFLAGS)
- AC_SUBST(PROGRAMS_GSTMIXER)
+ ])
fi
+AC_SUBST(GSTMIXER_CFLAGS)
+AC_SUBST(GSTMIXER_LIBS)
+AM_CONDITIONAL(HAVE_GSTMIXER, [test x$have_gstmixer = xyes])
-AC_OUTPUT([
+CFLAGS="$CFLAGS $WARN_CFLAGS"
+AC_SUBST(CFLAGS)
+AC_SUBST(CPPFLAGS)
+AC_SUBST(LIBS)
+AC_SUBST(LDFLAGS)
+
+AC_CONFIG_FILES([
Makefile
po/Makefile.in
vu-meter/Makefile
@@ -512,35 +583,33 @@
vu-meter/vumeter.desktop.in
])
-echo ""
-echo "${PACKAGE} ${VERSION} has been configured as follows: "
-echo
-echo "Architecture: ${CDROM_HOST}"
-echo "Source code location: ${srcdir}"
-echo "Compiler: ${CC}"
-echo ""
-echo "cddb-slave: $enable_cddbslave"
-echo "gnome-cd: $enable_gnomecd"
-if test x$enable_gnomecd == xyes; then
- echo "System CDRom header: ${cdrom_header}"
- echo "Default CD device: ${default_cd_device}"
- echo "OS supports close tray: ${close_tray}"
-fi
-if test x$PROGRAMS_GSTMIXER != x; then
- echo "GStreamer mixer: yes"
-else
- echo "GStreamer mixer: no"
-fi
-if test x$PROGRAMS_GSTPROPS != x; then
- echo "GStreamer capplet: yes"
-else
- echo "GStreamer capplet: no"
-fi
-if test x$PROGRAMS_GRECORD != x; then
- echo "Sound Recorder: yes"
-else
- echo "Sound Recorder: no, reason:"
- echo "$PROGRAMS_GRECORD_ERROR"
+AC_OUTPUT
+
+echo "
+ ${PACKAGE} ${VERSION} has been configured as follows:
+
+ Prefix: ${prefix}
+ Source code location: ${srcdir}
+ Compiler: ${CC}
+ CFLAGS: ${CFLAGS}
+
+ GStreamer mixer: $have_gstmixer
+ GStreamer properties: $have_gstprops
+ GStreamer profiles: $have_profiles
+ Sound recorder: $have_grecord$grecord_reason
+
+ *Deprecated*:
+
+ vu-meter: $have_vumeter$vumeter_reason
+ cddb-slave: $have_cddbslave
+ gnome-cd: $have_gnomecd$gnomecd_reason"
+
+if test x$enable_gnomecd = xyes; then
+echo " System CDRom header: ${cdrom_header}
+ Default CD device: ${default_cd_device}
+ OS supports close tray: ${close_tray}
+ Architecture: ${CDROM_HOST}"
fi
-echo
+
+echo ""
Modified: trunk/gnome-cd/Makefile.am
==============================================================================
--- trunk/gnome-cd/Makefile.am (original)
+++ trunk/gnome-cd/Makefile.am Sun Sep 7 18:15:44 2008
@@ -6,7 +6,7 @@
GST_CFLAGS=
endif
-INCLUDES = \
+AM_CPPFLAGS = \
-I$(top_srcdir) \
$(GNOME_INCLUDEDIR) \
-I$(top_builddir) \
Modified: trunk/gnome-cd/access/Makefile.am
==============================================================================
--- trunk/gnome-cd/access/Makefile.am (original)
+++ trunk/gnome-cd/access/Makefile.am Sun Sep 7 18:15:44 2008
@@ -1,4 +1,4 @@
-INCLUDES = \
+AM_CPPFLAGS = \
-I$(top_srcdir) \
$(MEDIA_CFLAGS) \
-I$(top_srcdir)/cddb-slave2 \
Modified: trunk/grecord/src/Makefile.am
==============================================================================
--- trunk/grecord/src/Makefile.am (original)
+++ trunk/grecord/src/Makefile.am Sun Sep 7 18:15:44 2008
@@ -1,6 +1,6 @@
## Process this file with automake to produce Makefile.in
-INCLUDES = \
+AM_CPPFLAGS = \
-DGNOMELOCALEDIR=\""$(prefix)/$(DATADIRNAME)/locale"\" \
-I$(top_srcdir) \
-I$(top_srcdir)/grecord/src/recent-files/ \
Modified: trunk/gst-mixer/src/Makefile.am
==============================================================================
--- trunk/gst-mixer/src/Makefile.am (original)
+++ trunk/gst-mixer/src/Makefile.am Sun Sep 7 18:15:44 2008
@@ -1,4 +1,4 @@
-INCLUDES = \
+AM_CPPFLAGS = \
$(GSTMIXER_CFLAGS) \
-DGNOMELOCALEDIR=\""$(datadir)/locale"\" \
-DDATA_DIR=\""$(pkgdatadir)"\" \
Modified: trunk/gstreamer-properties/Makefile.am
==============================================================================
--- trunk/gstreamer-properties/Makefile.am (original)
+++ trunk/gstreamer-properties/Makefile.am Sun Sep 7 18:15:44 2008
@@ -22,7 +22,7 @@
Desktop_in_files = gstreamer-properties.desktop.in.in
desktop_DATA = $(Desktop_in_files:.desktop.in.in=.desktop)
-INCLUDES = \
+AM_CPPFLAGS = \
$(GSTPROPS_CFLAGS) \
-DGSTPROPS_GLADEDIR=\""$(gladedir)"\" \
-DGSTPROPS_ICONDIR=\""$(iconsdir)"\" \
Modified: trunk/m4/as-version.m4
==============================================================================
--- trunk/m4/as-version.m4 (original)
+++ trunk/m4/as-version.m4 Sun Sep 7 18:15:44 2008
@@ -1,66 +1,71 @@
-dnl as-version.m4 0.1.0
+dnl as-version.m4 0.2.0
dnl autostars m4 macro for versioning
dnl Thomas Vander Stichele <thomas at apestaart dot org>
-dnl $Id: as-version.m4,v 1.4 2004/06/01 09:40:05 thomasvs Exp $
+dnl $Id: as-version.m4,v 1.15 2006/04/01 09:40:24 thomasvs Exp $
-dnl AS_VERSION(PACKAGE, PREFIX, MAJOR, MINOR, MICRO, NANO,
-dnl ACTION-IF-NO-NANO, [ACTION-IF-NANO])
+dnl AS_VERSION
dnl example
-dnl AS_VERSION(gstreamer, GST_VERSION, 0, 3, 2,)
-dnl for a 0.3.2 release version
+dnl AS_VERSION
dnl this macro
-dnl - defines [$PREFIX]_MAJOR, MINOR and MICRO
-dnl - if NANO is empty, then we're in release mode, else in cvs/dev mode
-dnl - defines [$PREFIX], VERSION, and [$PREFIX]_RELEASE
-dnl - executes the relevant action
-dnl - AC_SUBST's PACKAGE, VERSION, [$PREFIX] and [$PREFIX]_RELEASE
-dnl as well as the little ones
+dnl - AC_SUBST's PACKAGE_VERSION_MAJOR, _MINOR, _MICRO
+dnl - AC_SUBST's PACKAGE_VERSION_RELEASE,
+dnl which can be used for rpm release fields
dnl - doesn't call AM_INIT_AUTOMAKE anymore because it prevents
-dnl maintainer mode from running ok
+dnl maintainer mode from running correctly
dnl
-dnl don't forget to put #undef [$2] and [$2]_RELEASE in acconfig.h
+dnl don't forget to put #undef PACKAGE_VERSION_RELEASE in acconfig.h
dnl if you use acconfig.h
AC_DEFUN([AS_VERSION],
[
- PACKAGE=[$1]
- [$2]_MAJOR=[$3]
- [$2]_MINOR=[$4]
- [$2]_MICRO=[$5]
- NANO=[$6]
- [$2]_NANO=$NANO
- if test "x$NANO" = "x" || test "x$NANO" = "x0";
- then
- AC_MSG_NOTICE(configuring [$1] for release)
- VERSION=[$3].[$4].[$5]
- [$2]_RELEASE=1
- dnl execute action
- ifelse([$7], , :, [$7])
+ PACKAGE_VERSION_MAJOR=$(echo AC_PACKAGE_VERSION | cut -d'.' -f1)
+ PACKAGE_VERSION_MINOR=$(echo AC_PACKAGE_VERSION | cut -d'.' -f2)
+ PACKAGE_VERSION_MICRO=$(echo AC_PACKAGE_VERSION | cut -d'.' -f3)
+
+ AC_SUBST(PACKAGE_VERSION_MAJOR)
+ AC_SUBST(PACKAGE_VERSION_MINOR)
+ AC_SUBST(PACKAGE_VERSION_MICRO)
+])
+
+dnl AS_NANO(ACTION-IF-NO-NANO, [ACTION-IF-NANO])
+
+dnl requires AC_INIT to be called before
+dnl For projects using a fourth or nano number in your versioning to indicate
+dnl development or prerelease snapshots, this macro allows the build to be
+dnl set up differently accordingly.
+
+dnl this macro:
+dnl - parses AC_PACKAGE_VERSION, set by AC_INIT, and extracts the nano number
+dnl - sets the variable PACKAGE_VERSION_NANO
+dnl - sets the variable PACKAGE_VERSION_RELEASE, which can be used
+dnl for rpm release fields
+dnl - executes ACTION-IF-NO-NANO or ACTION-IF-NANO
+
+dnl example:
+dnl AS_NANO(RELEASE="yes", RELEASE="no")
+
+AC_DEFUN([AS_NANO],
+[
+ AC_MSG_CHECKING(nano version)
+
+ NANO=$(echo AC_PACKAGE_VERSION | cut -d'.' -f4)
+
+ if test x"$NANO" = x || test "x$NANO" = "x0" ; then
+ AC_MSG_RESULT([0 (release)])
+ NANO=0
+ PACKAGE_VERSION_RELEASE=1
+ ifelse([$1], , :, [$1])
else
- AC_MSG_NOTICE(configuring [$1] for development with nano $NANO)
- VERSION=[$3].[$4].[$5].$NANO
- [$2]_RELEASE=0.`date +%Y%m%d.%H%M%S`
- dnl execute action
- ifelse([$8], , :, [$8])
+ AC_MSG_RESULT($NANO)
+ PACKAGE_VERSION_RELEASE=0.`date +%Y%m%d.%H%M%S`
+ ifelse([$2], , :, [$2])
fi
-
- [$2]=$VERSION
- AC_DEFINE_UNQUOTED([$2], "$[$2]", [Define the version])
- AC_SUBST([$2])
- AC_DEFINE_UNQUOTED([$2]_RELEASE, "$[$2]_RELEASE", [Define the release version])
- AC_SUBST([$2]_RELEASE)
-
- AC_SUBST([$2]_MAJOR)
- AC_SUBST([$2]_MINOR)
- AC_SUBST([$2]_MICRO)
- AC_SUBST([$2]_NANO)
- AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Define the package name])
- AC_SUBST(PACKAGE)
- AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Define the version])
- AC_SUBST(VERSION)
+ PACKAGE_VERSION_NANO=$NANO
+ AC_SUBST(PACKAGE_VERSION_NANO)
+ AC_SUBST(PACKAGE_VERSION_RELEASE)
])
Modified: trunk/vu-meter/Makefile.am
==============================================================================
--- trunk/vu-meter/Makefile.am (original)
+++ trunk/vu-meter/Makefile.am Sun Sep 7 18:15:44 2008
@@ -2,7 +2,7 @@
icondir = $(datadir)/icons/hicolor/48x48/apps
-INCLUDES = \
+AM_CPPFLAGS = \
-DGNOMELOCALEDIR=\""$(prefix)/$(DATADIRNAME)/locale"\" \
$(VUMETER_CFLAGS) \
-DGNOME_ICONDIR=\""$(pixmapdir)"\"
[
Date Prev][
Date Next] [
Thread Prev][
Thread Next]
[
Thread Index]
[
Date Index]
[
Author Index]
