[gst-debugger] Replace autotools with meson
- From: Marcin Kolny <mkolny src gnome org>
- To: commits-list gnome org
- Cc:
- Subject: [gst-debugger] Replace autotools with meson
- Date: Sun, 1 Oct 2017 17:02:47 +0000 (UTC)
commit ae104e7f2598bacd51ede5d2042511496228ec7c
Author: Marcin Kolny <marcin kolny gmail com>
Date: Sun Oct 1 14:19:14 2017 +0100
Replace autotools with meson
INSTALL | 370 ------
Makefile.am | 18 -
autogen.sh | 55 -
build/ax_cxx_compile_stdcxx_11.m4 | 168 ---
build/boost.m4 | 1455 ---------------------
build/dist-changelog.am | 34 -
configure.ac | 93 --
meson.build | 44 +
po/meson.build | 2 +
src/Makefile.am | 1 -
src/common/Makefile.am | 39 -
src/common/meson.build | 36 +
src/debugserver/Makefile.am | 17 -
src/debugserver/meson.build | 16 +
src/gst-debugger/Makefile.am | 106 --
src/gst-debugger/addins/addins-notifier.h | 2 +-
src/gst-debugger/controller/command_factory.h | 2 +-
src/gst-debugger/controller/tcp_client.h | 2 +-
src/gst-debugger/controller/topology_controller.h | 2 +-
src/gst-debugger/meson.build | 110 ++
src/gst-debugger/modules/base_main_module.h | 2 +-
src/gst-debugger/modules/gst_properties_module.h | 2 +-
src/gst-debugger/ui_utils.h | 2 +-
src/meson.build | 3 +
src/stamp-h1 | 1 -
src/tests/main.cpp | 10 -
src/tests/serializer-test.cpp | 74 --
27 files changed, 218 insertions(+), 2448 deletions(-)
---
diff --git a/meson.build b/meson.build
new file mode 100644
index 0000000..14211bf
--- /dev/null
+++ b/meson.build
@@ -0,0 +1,44 @@
+project('gst-debugger', 'c', 'cpp',
+ license: 'GPL',
+ version: '0.90.0',
+ meson_version: '>= 0.40.1',
+ default_options: [
+ 'cpp_std=c++11',
+ 'warning_level=1',
+ ],
+)
+
+# Modules
+gnome = import('gnome')
+
+# Dependencies
+glib_version = '>=2.41.1'
+gio_dep = dependency('gio-2.0', version : glib_version)
+gmoduledep = dependency('gmodule-2.0', version : glib_version)
+gobjectdep = dependency('gobject-2.0', version : glib_version)
+gst_dep = dependency('gstreamer-1.0', version : '>=1.8.0')
+gstmm_dep = dependency('gstreamermm-1.0')
+gtkmm_dep = dependency('gtkmm-3.0', version : '>=3.14.0')
+x11_dep = dependency('x11')
+gvc_dep = dependency('libgvc', version : '>=2.38')
+libprotobuf_c_dep = dependency('libprotobuf-c', version : '>=1.1.1')
+protobuf_dep = dependency('protobuf', version : '>=2.6.1')
+boost_dep = dependency('boost', modules : ['filesystem', 'system'], version : '>=1.55')
+thread_dep = dependency('threads')
+
+# Dependency apps
+protoc_c = find_program('protoc-c')
+
+# Configuration file
+conf = configuration_data()
+conf.set_quoted('PACKAGE_NAME', 'gnome-paint')
+conf.set_quoted('VERSION', meson.project_version())
+conf.set_quoted('GST_DEBUGGER_LOCALEDIR', join_paths(get_option('prefix'), get_option('datadir'), 'locale'))
+conf.set('GETTEXT_PACKAGE', 'PACKAGE_NAME')
+configure_file(output : 'config.h',
+ configuration : conf)
+config_inc_dir = include_directories('.')
+
+# Subdirectories
+subdir('src')
+subdir('po')
diff --git a/po/meson.build b/po/meson.build
new file mode 100644
index 0000000..9debb6f
--- /dev/null
+++ b/po/meson.build
@@ -0,0 +1,2 @@
+i18n = import ('i18n')
+i18n.gettext ('gst-debugger', preset: 'glib')
\ No newline at end of file
diff --git a/src/common/meson.build b/src/common/meson.build
new file mode 100644
index 0000000..75068a5
--- /dev/null
+++ b/src/common/meson.build
@@ -0,0 +1,36 @@
+protoc_c_gen = generator(protoc_c,
+ output : ['@BASENAME@.pb-c.c', '@BASENAME@.pb-c.h'],
+ arguments : ['--proto_path=@CURRENT_SOURCE_DIR@', '--c_out=@BUILD_DIR@', '@INPUT@'])
+protoc_c_gen_src = protoc_c_gen.process('gstdebugger.proto')
+
+generate_c_proto = custom_target('generate_proto',
+ output : ['gstdebugger.pb-c.h'],
+ input : 'gstdebugger.proto',
+ command : [
+ protoc_c,
+ '--proto_path=' + meson.current_source_dir(),
+ '--c_out=' + meson.current_source_dir(),
+ join_paths(meson.current_source_dir(), 'gstdebugger.proto')])
+
+gstdebugger_common_sources = [
+ 'gst-utils.c',
+ 'protocol-utils.c',
+ 'serializer.c']
+
+gstdebugger_common_deps = [
+ gio_dep,
+ gst_dep,
+ libprotobuf_c_dep]
+
+gstdebugger_common_lib = static_library(
+ 'gstdebugger-common',
+ gstdebugger_common_sources,
+ generate_c_proto,
+ protoc_c_gen_src,
+ dependencies : gstdebugger_common_deps,
+ install : true)
+
+gstdebugger_common_dep = declare_dependency(
+ link_with : gstdebugger_common_lib,
+ include_directories : include_directories('..'),
+ dependencies : gstdebugger_common_deps)
diff --git a/src/debugserver/meson.build b/src/debugserver/meson.build
new file mode 100644
index 0000000..d7b4e67
--- /dev/null
+++ b/src/debugserver/meson.build
@@ -0,0 +1,16 @@
+gstdebugger_sources = [
+ 'gstdebugserver.c',
+ 'gstdebugservertcp.c',
+ 'gstdebugserverlog.c',
+ 'gstdebugservermessage.c',
+ 'gstdebugservertypes.c',
+ 'gstdebugserverqe.c',
+ 'gstdebugservertopology.c',
+ 'gstdebugserverhooks.c',
+ 'gstdebugserverbuffer.c']
+
+gstdebugger = shared_library(
+ 'gstdebugserver',
+ gstdebugger_sources,
+ dependencies : gstdebugger_common_dep,
+ install : true)
diff --git a/src/gst-debugger/addins/addins-notifier.h b/src/gst-debugger/addins/addins-notifier.h
index 0e8f811..28fbd12 100644
--- a/src/gst-debugger/addins/addins-notifier.h
+++ b/src/gst-debugger/addins/addins-notifier.h
@@ -8,7 +8,7 @@
#ifndef SRC_GST_DEBUGGER_ADDINS_ADDINS_NOTIFIER_H_
#define SRC_GST_DEBUGGER_ADDINS_ADDINS_NOTIFIER_H_
-#include <common/gstdebugger.pb.h>
+#include "gstdebugger.pb.h"
#include <gstreamermm.h>
diff --git a/src/gst-debugger/controller/command_factory.h b/src/gst-debugger/controller/command_factory.h
index 994fdcf..4f31211 100644
--- a/src/gst-debugger/controller/command_factory.h
+++ b/src/gst-debugger/controller/command_factory.h
@@ -10,7 +10,7 @@
#include "base_controller.h"
-#include "common/gstdebugger.pb.h"
+#include "gstdebugger.pb.h"
#include <boost/optional/optional.hpp>
diff --git a/src/gst-debugger/controller/tcp_client.h b/src/gst-debugger/controller/tcp_client.h
index e460a56..7637a2d 100644
--- a/src/gst-debugger/controller/tcp_client.h
+++ b/src/gst-debugger/controller/tcp_client.h
@@ -8,7 +8,7 @@
#ifndef SRC_GST_DEBUGGER_GST_DEBUGGER_TCP_CLIENT_H_
#define SRC_GST_DEBUGGER_GST_DEBUGGER_TCP_CLIENT_H_
-#include "common/gstdebugger.pb.h"
+#include "gstdebugger.pb.h"
#include <sigc++/sigc++.h>
#include <giomm.h>
diff --git a/src/gst-debugger/controller/topology_controller.h
b/src/gst-debugger/controller/topology_controller.h
index 6c8f657..1b06adf 100644
--- a/src/gst-debugger/controller/topology_controller.h
+++ b/src/gst-debugger/controller/topology_controller.h
@@ -10,7 +10,7 @@
#include "base_controller.h"
-#include "common/gstdebugger.pb.h"
+#include "gstdebugger.pb.h"
#include <mutex>
diff --git a/src/gst-debugger/meson.build b/src/gst-debugger/meson.build
new file mode 100644
index 0000000..45293c0
--- /dev/null
+++ b/src/gst-debugger/meson.build
@@ -0,0 +1,110 @@
+proto_src_path = join_paths(meson.current_source_dir(), '..', 'common')
+protoc_gen = generator(find_program('protoc'),
+ output : ['@BASENAME pb cc', '@BASENAME@.pb.h'],
+ arguments : ['--proto_path=' + proto_src_path, '--cpp_out=@BUILD_DIR@', join_paths(proto_src_path,
'gstdebugger.proto')])
+
+protoc_gen_src = protoc_gen.process(join_paths(proto_src_path, 'gstdebugger.proto'))
+
+gstd_resources = gnome.compile_resources(
+ 'gst-debugger-resources', 'gst-debugger-resources.xml',
+ source_dir : '.',
+ c_name : 'gst_debugger')
+
+gst_debugger_sources = [
+ 'main.cpp',
+ 'main_window.cpp',
+ 'main_window.h',
+ 'controller/controller.cpp',
+ 'controller/controller.h',
+ 'controller/command_factory.cpp',
+ 'controller/command_factory.h',
+ 'ui_utils.cpp',
+ 'ui_utils.h',
+ gstd_resources,
+ 'controller/base_controller.h',
+ 'controller/connection_controller.h',
+ 'controller/tcp_client.cpp',
+ 'controller/tcp_client.h',
+ 'controller/addins_controller.cpp',
+ 'controller/addins_controller.h',
+ 'dialogs/connection_properties_dialog.cpp',
+ 'dialogs/connection_properties_dialog.h',
+ 'dialogs/remote_data_dialog.h',
+ 'modules/control_module.h',
+ 'modules/base_main_module.cpp',
+ 'modules/base_main_module.h',
+ 'modules/log_module.cpp',
+ 'modules/log_module.h',
+ 'modules/main_module.cpp',
+ 'modules/main_module.h',
+ 'controller/iview.h',
+ 'controller/topology_controller.cpp',
+ 'controller/topology_controller.h',
+ 'common_model_columns.h',
+ 'modules/message_module.cpp',
+ 'modules/message_module.h',
+ 'models/gst_enum_model.h',
+ 'models/gst_factory_model.cpp',
+ 'models/gst_factory_model.h',
+ 'models/gst_pipeline_model.cpp',
+ 'models/gst_pipeline_model.h',
+ 'modules/event_module.cpp',
+ 'modules/event_module.h',
+ 'modules/query_module.cpp',
+ 'modules/query_module.h',
+ 'pipeline-drawer/graph_module.cpp',
+ 'pipeline-drawer/graph_module.h',
+ 'pipeline-drawer/gst_bin_to_dot_converter.cpp',
+ 'pipeline-drawer/gst_bin_to_dot_converter.h',
+ 'graphviz-plugin/graphviz-gstdebugger.h',
+ 'graphviz-plugin/gvdevice_gstdebugger.c',
+ 'graphviz-plugin/gvplugin_gstdebugger.c',
+ 'controller/element_path_processor.h',
+ 'modules/qe_control_module.h',
+ 'dialogs/enums_dialog.cpp',
+ 'dialogs/enums_dialog.h',
+ 'dialogs/buffer_data_dialog.cpp',
+ 'dialogs/buffer_data_dialog.h',
+ 'dialogs/factories_dialog.cpp',
+ 'dialogs/factories_dialog.h',
+ 'modules/gst_properties_module.cpp',
+ 'modules/gst_properties_module.h',
+ 'modules/buffer_module.cpp',
+ 'modules/buffer_module.h',
+ 'models/gst_klass_model.h',
+ 'dialogs/klasses_dialog.h',
+ 'dialogs/klasses_dialog.cpp',
+ 'gvalue-converter/gvalue_base.cpp',
+ 'gvalue-converter/gvalue_base.h',
+ 'gvalue-converter/gvalue_unknown.cpp',
+ 'gvalue-converter/gvalue_unknown.h',
+ 'gvalue-converter/gvalue_numeric.cpp',
+ 'gvalue-converter/gvalue_numeric.h',
+ 'gvalue-converter/gvalue_boolean.cpp',
+ 'gvalue-converter/gvalue_boolean.h',
+ 'gvalue-converter/gvalue_caps.cpp',
+ 'gvalue-converter/gvalue_caps.h',
+ 'gvalue-converter/gvalue_string.cpp',
+ 'gvalue-converter/gvalue_string.h',
+ 'gvalue-converter/gvalue_enum.cpp',
+ 'gvalue-converter/gvalue_enum.h',
+ 'gvalue-converter/gvalue_flags.cpp',
+ 'gvalue-converter/gvalue_flags.h',
+ 'addins/addins-interface.h',
+ 'addins/addins-notifier.h']
+
+
+executable(
+ 'gst-debugger',
+ gst_debugger_sources,
+ protoc_gen_src,
+ include_directories : config_inc_dir,
+ dependencies : [
+ gtkmm_dep,
+ gstmm_dep,
+ gstdebugger_common_dep,
+ gvc_dep,
+ x11_dep,
+ thread_dep,
+ boost_dep,
+ protobuf_dep])
diff --git a/src/gst-debugger/modules/base_main_module.h b/src/gst-debugger/modules/base_main_module.h
index 55819ba..212b921 100644
--- a/src/gst-debugger/modules/base_main_module.h
+++ b/src/gst-debugger/modules/base_main_module.h
@@ -12,7 +12,7 @@
#include "controller/iview.h"
-#include "common/gstdebugger.pb.h"
+#include "gstdebugger.pb.h"
#include <gtkmm/liststore.h>
#include <gtkmm/treeview.h>
diff --git a/src/gst-debugger/modules/gst_properties_module.h
b/src/gst-debugger/modules/gst_properties_module.h
index b6ab128..2b8e1b0 100644
--- a/src/gst-debugger/modules/gst_properties_module.h
+++ b/src/gst-debugger/modules/gst_properties_module.h
@@ -11,7 +11,7 @@
#include "controller/iview.h"
#include "gvalue-converter/gvalue_base.h"
-#include "common/gstdebugger.pb.h"
+#include "gstdebugger.pb.h"
#include <gtkmm.h>
diff --git a/src/gst-debugger/ui_utils.h b/src/gst-debugger/ui_utils.h
index 53b7987..6b830e7 100644
--- a/src/gst-debugger/ui_utils.h
+++ b/src/gst-debugger/ui_utils.h
@@ -8,7 +8,7 @@
#ifndef SRC_GST_DEBUGGER_UI_UTILS_H_
#define SRC_GST_DEBUGGER_UI_UTILS_H_
-#include "common/gstdebugger.pb.h"
+#include "gstdebugger.pb.h"
#include <gstreamermm.h>
#include <gtkmm.h>
diff --git a/src/meson.build b/src/meson.build
new file mode 100644
index 0000000..250c20b
--- /dev/null
+++ b/src/meson.build
@@ -0,0 +1,3 @@
+subdir('common')
+subdir('debugserver')
+subdir('gst-debugger')
[
Date Prev][
Date Next] [
Thread Prev][
Thread Next]
[
Thread Index]
[
Date Index]
[
Author Index]
