[gdl/pgriffis/meson-build] Initial Meson port

[Patrick Griffis <pgriffis src gnome org>]

commit 5ef91f41995d5b9c74c4bf0ffe2e0ffd20d53d41
Author: Patrick Griffis <pgriffis igalia com>
Date:   Mon Oct 18 11:15:27 2021 -0500

    Initial Meson port

 gdl/meson.build | 70 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 meson.build     | 38 +++++++++++++++++++++++++++++++
 2 files changed, 108 insertions(+)
---
diff --git a/gdl/meson.build b/gdl/meson.build
new file mode 100644
index 0000000..4cd4bb3
--- /dev/null
+++ b/gdl/meson.build
@@ -0,0 +1,70 @@
+gnome = import('gnome')
+
+headers = [
+  'gdl.h',
+  'gdl-dock.h',
+  'gdl-dock-object.h',
+  'gdl-dock-master.h',
+  'gdl-dock-item.h',
+  'gdl-dock-item-grip.h',
+  'gdl-dock-layout.h',
+  'gdl-dock-bar.h',
+  'gdl-dock-placeholder.h',
+]
+
+
+enums = gnome.mkenums_simple('libgdltypebuiltins',
+  sources: headers,
+  header_prefix: '''#include <gdl/gdl.h>''',
+  install_header: true,
+  install_dir: gdl_includedir,
+)
+
+marshals = gnome.genmarshal('libgdlmarshal',
+  sources: 'libgdlmarshal.list',
+  prefix: 'gdl_marshal',
+)
+
+install_headers(headers, subdir: gdl_header_subdir)
+
+sources = [
+  enums,
+  marshals,
+  'gdl-dock-object.c',
+  'gdl-dock-master.c',
+  'gdl-dock.c',
+  'gdl-dock-item.c',
+  'gdl-dock-item-button-image.h',
+  'gdl-dock-item-button-image.c',
+  'gdl-dock-item-grip.h',
+  'gdl-dock-item-grip.c',
+  'gdl-dock-notebook.h',
+  'gdl-dock-notebook.c',
+  'gdl-dock-paned.c',
+  'gdl-dock-paned.h',
+  'deprecated/gdl-dock-tablabel.c',
+  'deprecated/gdl-dock-tablabel.h',
+  'gdl-dock-layout.c',
+  'gdl-dock-placeholder.c',
+  'gdl-dock-bar.c',
+  'gdl-switcher.c',
+  'gdl-switcher.h',
+  'gdl-preview-window.h',
+  'gdl-preview-window.c',
+  'gdl-deprecated.c',
+]
+
+library('gdl-3',
+  sources: sources,
+  version: '5.0.9',
+  include_directories: include_directories('..', '.'),
+  c_args: [
+    '-DGETTEXT_PACKAGE="gdl-3"',
+    '-DG_LOG_DOMAIN="Gdl"',
+  ],
+  dependencies: [
+    xml_dep,
+    gtk_dep,
+  ],
+  install: true,
+)
\ No newline at end of file
diff --git a/meson.build b/meson.build
new file mode 100644
index 0000000..267e66d
--- /dev/null
+++ b/meson.build
@@ -0,0 +1,38 @@
+project('gdl', 'c',
+  version: '3.40.0',
+  meson_version: '>= 0.57.0',
+  default_options: [
+    'c_std=c99',
+    'warning_level=0',
+  ]
+)
+
+cc = meson.get_compiler('c')
+
+xml_dep = dependency('libxml-2.0', version: '>= 2.2.8')
+gtk_dep = dependency('gtk+-3.0')
+
+if host_machine.system() == 'windows'
+  add_project_arguments('-mms-bitfields', language: 'c')
+endif
+
+gdl_header_subdir = 'libgdl-3.0' / 'gdl'
+gdl_includedir = get_option('prefix') / get_option('includedir') / gdl_header_subdir
+
+conf = configuration_data()
+conf.set('VERSION', meson.project_version())
+conf.set('prefix', get_option('prefix'))
+conf.set('exec_prefix', get_option('prefix'))
+conf.set('libdir', get_option('prefix') / get_option('libdir'))
+conf.set('includedir', get_option('prefix') / get_option('includedir'))
+conf.set('datarootdir', get_option('prefix') / get_option('datadir'))
+
+configure_file(
+  input: 'gdl-3.0.pc.in',
+  output: 'gdl-3.0.pc',
+  install: true,
+  install_dir: get_option('libdir') / 'pkgconfig',
+  configuration: conf,
+)
+
+subdir('gdl')
\ No newline at end of file